Galaxy of Universes
của Zu Phạm, visualizer
Just a small explosion somewhere.
Cách cài, mã SHA-256 và mã nguồn
Bấm Áp dụng: MusicBar tự tải về, kiểm tra mã SHA-256 rồi mặc lên taskbar; có rồi thì mặc luôn. Cần MusicBar 1.8 trở lên.
SHA-256 5fc344c3638c614d9805d252e4ec38e96731ec41a515d45414c8449094046986
//! name: Galaxy of universes
//! author: Zu Phạm
//! kind: visualizer
//! description: fractal formula
#define BULGE_SIZE (0.1)
#define BULGE_RADIUS (0.4)
#define BULGE_STRENGTH (1.0)
#define BULGE_GLOW (1.1)
#define BULGE_GLOW_RADIUS (0.5)
#define BULGE_FLATTEN (1.0)
#define HAZE_STRENGTH (0.7)
#define HAZE_RADIUS (0.9)
#define HAZE_FALLOFF (1.6)
#define HAZE_WIDTH (1.4)
#define HAZE_COLOR (float3(1.0, 0.97, 0.93))
#define BULGE_CORE_COLOR (float3(1.0, 1.0, 1.0))
#define BULGE_EDGE_COLOR (float3(0.92, 0.95, 1.0))
float4 main(float2 uv : TEXCOORD) : COLOR
{
float2 q = uv - 0.5;
float len = length(q);
float t = time * 0.1
+ ((0.25 + 0.05 * sin(time * 0.1))
/ (len + 0.07)) * 2.2;
float si = sin(t);
float co = cos(t);
float2 rot;
rot.x = q.x * co + q.y * si;
rot.y = -q.x * si + q.y * co;
float v1 = 0.0;
float v2 = 0.0;
float v3 = 0.0;
float s = 0.0;
[loop]
for (int i = 0; i < 90; i++)
{
float3 p = s * float3(rot, 0.0);
p += float3(0.22, 0.3, s - 1.5 - sin(time * 0.13) * 0.1);
[loop]
for (int j = 0; j < 8; j++)
{
float d = max(dot(p, p), 0.000001);
p = abs(p) / d - 0.659;
}
float pp = dot(p, p);
v1 += pp * 0.0015
* (1.8 + sin(len * 13.0 + 0.5 - time * 0.2));
v2 += pp * 0.0013
* (1.5 + sin(len * 14.5 + 1.2 - time * 0.3));
v3 += length(p.xy) * 0.003;
s += 0.035;
}
v1 *= smoothstep(0.7, 0.0, len);
v2 *= smoothstep(0.5, 0.0, len);
v3 *= smoothstep(0.9, 0.0, len);
float3 col = float3(
v3 * (1.5 + sin(time * 0.2) * 0.4),
(v1 + v3) * 0.3,
v2
);
col += smoothstep(0.2, 0.0, len) * 0.85;
col += smoothstep(0.0, 0.6, v3) * 0.3;
float aspect = max(size.x, 1.0) / max(size.y, 1.0);
float2 bq = float2(q.x * aspect, q.y * BULGE_FLATTEN);
float br = length(bq);
float bulge = exp(-1.6 * sqrt(br / BULGE_SIZE));
bulge *= smoothstep(0.8, 0.0, br);
bulge *= 1.0 + 0.05 * sin(time * 0.3);
float lum = dot(col, float3(0.299, 0.587, 0.114));
float3 warm = lerp(BULGE_EDGE_COLOR, BULGE_CORE_COLOR, saturate(bulge * 1.5));
warm /= dot(warm, float3(0.299, 0.587, 0.114));
float bright = min(max(lum * 1.3, 0.55 + 1.5 * bulge), 1.0);
float mask = smoothstep(1.0, 0.0, br / BULGE_RADIUS) * saturate(BULGE_STRENGTH);
col = lerp(col, warm * bright, mask);
float gr = br / BULGE_GLOW_RADIUS;
float halo = 0.50 * exp(-gr * 7.0)
+ 0.30 * exp(-gr * 2.8)
+ 0.20 / (1.0 + gr * gr * 9.0);
halo *= smoothstep(1.6, 0.5, br);
col += float3(1.0, 1.0, 1.0) * halo * BULGE_GLOW;
col = min(pow(abs(col), 1.2), 1.0);
float hr = length(float2(bq.x / HAZE_WIDTH, bq.y)) / HAZE_RADIUS;
float haze = exp(-HAZE_FALLOFF * pow(hr, 0.4));
haze *= smoothstep(2.6, 0.8, hr);
col = min(col + HAZE_COLOR * haze * HAZE_STRENGTH, 1.0);
return paint(col, 1.0);
}